Talking to an RS/6000

[Tim Fredrick]

John.Burton at f98.n250.z1.FidoNet.Org (John Burton) writes:
>
>I have an RS/6000 running AIX 3.1.5 and connected to the internet.
>I also have an IBM-PC/XT (running DOS 4.01) and dialup access to 
>an internet terminal server using Procomm Plus.
...
>I JUST CAN'T TRANSFER FILES!!!
>
>Can someone suggest a way to do this on the RS/6000? Apparently I don't
>have Kermit on the RS/6000 set up properly...can someone tell me how it
>*should* be setup?
>
>+--------------------------------------------------------------------+
>| John Burton                                                        |
>+--------------------------------------------------------------------+

For a limited time you can anon ftp kermit from acd.ucar.edu (128.117.32.1).

We have a similar setup here.  Be sure that you are logging in with
Even Parity and 7 bits and have your terminal server set to the same (we have
an emulex terminal server).  For protocol transfers you should use the
bsd line discipline like this:

	stty disp bsd ; KERMIT COMMANDS ; stty disp posix

With that, kermit should work.

If you are using Procomm-Plus to connect, you should have 2.0 or greater & have
the file type set appropriately. (Press Alt-S, then P for Protocol, then K
for kermit options, and H for file type.  The file type should be binary or
text depending on what you want to transfer).

We included some shellscripts to help us, called sk and rk for "send kermit
file" and "receive kermit file".  They look like this:


-------------------------------------- sk ------------------------------------

#! /bin/csh
# ***************************************************************************
# *  sk - Send a kermit file.                                               *
# *                                                                         *
# *  This front end will send the given file in kermit format.  If there    *
# *  are two arguments, then the first is the local name and the 2nd is the *
# *  remote (desktop computer) name.                                        *
# *                                                                         *
# *  To Call:   sk [-b] unix-filename PC-filename                           *
# *  Flags:     -b == binary mode.                                          *
# *                                                                         *
# *  04/07/91 - Timothy Fredrick, (c) NCAR/ACD.                             *
# ***************************************************************************
set flg =
while ($#argv > 0)
    switch ($1)
	case -b:
	    set flg = -i
	    breaksw
	default:
            if ( $?sfile ) then
               set rfile = $1
            else
               set sfile = $1
            endif
    endsw
    shift argv
end

while ( ! -f $sfile )
   echo -n 'sk> Enter filename to send (q==quit): '
   set sfile = $<
   if ("$sfile" == "q") exit
   if ( ! -f $sfile ) echo "sk> $sfile does not exist."
   end

stty disp bsd
echo "sk> Don't forget in procomm to set your transfer type <ALT-s><p><k><h>"
if ($?rfile) then
  kermit $flg -s $sfile -a $rfile
else
  kermit $flg -s $sfile
endif
stty disp posix
-----------------------------------------------------------------------------
------------------------------------ rk -------------------------------------

#! /bin/csh
# ***************************************************************************
# *  rk - Use Kermit to receive a file.                                     *
# *                                                                         *
# *  This front end will get the given file in kermit format.   There are   *
# *  no arguments because the PC or MacIntosh will determine the filename.  *
# *                                                                         *
# *  To Call:   rk [-b] [filename]                                          *
# *  Flags:     -b == binary transfer mode                                  *
# *                                                                         *
# *  04/07/91 - Timothy Fredrick, (c) NCAR/ACD.                             *
# ***************************************************************************
while ($#argv > 0)
    switch ($1)
	case -b:
	    set flg = -i
	    breaksw
	default:
	    set fn = $argv
    endsw
    shift argv
end
if ( $?flg ) then
  echo "Be sure your terminal emulator sends Binary or MacBinary kermit"
else
  echo "Be sure your terminal emulator sends Text kermit"
  set flg = 
endif
stty disp bsd
if ($?fn) then
   echo "Go into your terminal emulator now, and send your file"
   kermit $flg -k > $fn
else
   kermit $flg -r
endif
stty disp posix
------------------------------------------------------------------------------

Hope this all helps you.  Good luck.  --Tim